Im 3. Teil des KosmoBits Videos habe ich ab Minute 8:30 den angepassten Arduino Sketch der kürzlich hier vorgestellten Bond Theme Box erwähnt.

Damit der Sketch funktioniert, müsst ihr lediglich den Lichtsensor auf das Interaction Board stecken und folgenden Sketch (Achtung, besteht aus zwei Dateien!) auf den Kosmoduino übertragen.

KosmoBits Arduino Interaction Board

Hier Teil 1 des Sketches:

#include "pitches.h"
#include "KosmoBits_Pins.h"
#define NO_SOUND 0 // für die Pausen
 
int ldrPin = KOSMOBITS_SENSOR_PIN; // Lichtempfindlicher Widerstand
int speakerPin = KOSMOBITS_BUZZER_PIN; // Lautsprecher
 
// Thanks to
// http://garagelab.com/profiles/blogs/how-to-use-tone-function-arduino-playing-the-james-bond-theme
 
// Array mit Noten des Bond Theme
int16_t melody[] = {
  NOTE_E4,NOTE_F4,NOTE_F4,NOTE_F4,NOTE_F4,NOTE_E4,NOTE_E4,NOTE_E4,
  NOTE_E4,NOTE_G4,NOTE_G4,NOTE_G4,NOTE_G4,NOTE_E4,NOTE_E4,NOTE_E4,
  NOTE_E4,NOTE_F4,NOTE_F4,NOTE_F4,NOTE_F4,NOTE_E4,NOTE_E4,NOTE_E4,
  NOTE_E4,NOTE_G4,NOTE_G4,NOTE_G4,NOTE_G4,NOTE_E4,NOTE_E4,NOTE_E4,
  NOTE_DS5,NOTE_D5,NOTE_B4,NOTE_A4,NOTE_B4,
  NOTE_E4,NOTE_G4,NOTE_DS5,NOTE_D5,NOTE_G4,NOTE_B4,
  NOTE_B4,NOTE_FS5,NOTE_F5,NOTE_B4,NOTE_D5,NOTE_AS5,
  NOTE_A5,NOTE_F5,NOTE_A5,NOTE_DS6,NOTE_D6,NO_SOUND
};
 
// Dauer der einzelnen Noten
// Notenwert: 1 = ganze Note, 2 = halbe Note, 4 = Viertelnote usw.
int16_t noteDurations[] = {
  8,16,16,8,4,8,8,8,
  8,16,16,8,4,8,8,8,
  8,16,16,8,4,8,8,8,
  8,16,16,8,4,8,8,8,
  8,2,8,8,1,
  8,4,8,4,8,8,
  8,8,4,8,4,8,
  4,8,4,8,3,1
};
 
int songPace = 1450; // Dauer einer ganzen Note in Millisekunden
int melodyLength = 0;
 
int playState = 0; // 0 = ruhig warten bis es hell wird, 1 = Song spielt gerade, -1 = ruhig, warten bis es dunkel wird
int noteCount = 0; // Laufender Zaehler fuer aktuelle Position
 
 
void setup() {
 
  Serial.begin(9600);
  pinMode(speakerPin, OUTPUT);
 
  melodyLength = sizeof(melody) / sizeof(melody[0]);
 
  Serial.print ("Melody length: ");
  Serial.println (melodyLength);
  Serial.println ("------------");
}
 
void loop() {
 
  if (analogRead(ldrPin) > 100) { // es ist grade hell!
    if (playState == 0) { // warte ich gerade aufs loslegen?
      playState = 1;  // ja, also loslegen!
    }
  } else // es ist grade dunkel
  {
    // Spiele ich gerade oder warte ich darauf, dass es dunkel wird?
    if ((playState == 1) || (playState == -1)) { 
       playState = 0; // Setze Status auf 0 = Warten, bis es hell wird
       noteCount = 0;
    }
  }
 
  if (playState == 1) {
    int duration = songPace/noteDurations[noteCount]; // Aus Notenwert die Länge in Millisec berechnen
    tone(speakerPin, melody[noteCount], duration); // Note mit tone() spielen
    delay(duration*1.2); // Kurz warten vor naechster Note
    noteCount ++; // Notenzaehler erhoehen
    if (noteCount >= melodyLength) {  // Wenn letzte Note gespielt, Zaehler auf Anfang und Status auf Pause
      noteCount = 0;
      playState = -1;
    }
  }
 
  // Debug-Ausgaben auf dem Seriellen Monitor
  Serial.print(playState);
  Serial.print("   ");
  Serial.print(noteCount);
  Serial.print("   ");
  Serial.print(melody[noteCount]);
  Serial.print("   ");
  Serial.print(noteDurations[noteCount]);
  Serial.print("   ");  
  Serial.println(analogRead(A0));
 
}

Und die Datei „pitches.h“. Am besten im Arduino Editor mit dem kleinen blauen Pfeil rechts ein „Neues Tab“ erstellen, dieses „pitches.h“ benennen und diesen Inhalt hineinkopieren.

/*************************************************
 * Public Constants
 *************************************************/
 
#define NOTE_B0  31
#define NOTE_C1  33
#define NOTE_CS1 35
#define NOTE_D1  37
#define NOTE_DS1 39
#define NOTE_E1  41
#define NOTE_F1  44
#define NOTE_FS1 46
#define NOTE_G1  49
#define NOTE_GS1 52
#define NOTE_A1  55
#define NOTE_AS1 58
#define NOTE_B1  62
#define NOTE_C2  65
#define NOTE_CS2 69
#define NOTE_D2  73
#define NOTE_DS2 78
#define NOTE_E2  82
#define NOTE_F2  87
#define NOTE_FS2 93
#define NOTE_G2  98
#define NOTE_GS2 104
#define NOTE_A2  110
#define NOTE_AS2 117
#define NOTE_B2  123
#define NOTE_C3  131
#define NOTE_CS3 139
#define NOTE_D3  147
#define NOTE_DS3 156
#define NOTE_E3  165
#define NOTE_F3  175
#define NOTE_FS3 185
#define NOTE_G3  196
#define NOTE_GS3 208
#define NOTE_A3  220
#define NOTE_AS3 233
#define NOTE_B3  247
#define NOTE_C4  262
#define NOTE_CS4 277
#define NOTE_D4  294
#define NOTE_DS4 311
#define NOTE_E4  330
#define NOTE_F4  349
#define NOTE_FS4 370
#define NOTE_G4  392
#define NOTE_GS4 415
#define NOTE_A4  440
#define NOTE_AS4 466
#define NOTE_B4  494
#define NOTE_C5  523
#define NOTE_CS5 554
#define NOTE_D5  587
#define NOTE_DS5 622
#define NOTE_E5  659
#define NOTE_F5  698
#define NOTE_FS5 740
#define NOTE_G5  784
#define NOTE_GS5 831
#define NOTE_A5  880
#define NOTE_AS5 932
#define NOTE_B5  988
#define NOTE_C6  1047
#define NOTE_CS6 1109
#define NOTE_D6  1175
#define NOTE_DS6 1245
#define NOTE_E6  1319
#define NOTE_F6  1397
#define NOTE_FS6 1480
#define NOTE_G6  1568
#define NOTE_GS6 1661
#define NOTE_A6  1760
#define NOTE_AS6 1865
#define NOTE_B6  1976
#define NOTE_C7  2093
#define NOTE_CS7 2217
#define NOTE_D7  2349
#define NOTE_DS7 2489
#define NOTE_E7  2637
#define NOTE_F7  2794
#define NOTE_FS7 2960
#define NOTE_G7  3136
#define NOTE_GS7 3322
#define NOTE_A7  3520
#define NOTE_AS7 3729
#define NOTE_B7  3951
#define NOTE_C8  4186
#define NOTE_CS8 4435
#define NOTE_D8  4699
#define NOTE_DS8 4978

Das war’s schon. Die Melodie sollte immer abgespielt werden, wenn der Lichtsensor einen Wert über der angegebenen Schwelle misst, also z.B. wenn man das Interaction Board in einer Schachtel oder einer Schublade versteckt und diese dann öffnet.

 

 

Schreibe einen Kommentar

Deine E-Mail-Adresse wird nicht veröffentlicht. Erforderliche Felder sind mit * markiert.

Time limit is exhausted. Please reload the CAPTCHA.